Keygen int_0x80 with water_effect !

.486
.model  flat, stdcall
option  casemap :none   ; case sensitive

include keygen.inc

szFormat                       db       "%X",0
szSizeMax                      db       "Entrez moins de caractères !",0
szSizeMin                      db       "Entrez plus de caractères !",0
szCap                          db       "Keygen By int_0x80",0
szTitle                        db       "Error",0
szError                        db       "An error has occured",0

.data?
hInstance                      dd           ?
stWaveObj                      WAVE_OBJECT <?>
xWin                           dd           ?
hBitmap                        dd           ?
bitmp                          dd           ?
szName                         db   256 dup(?)
szSerial                       db   256 dup(?)
LenName                        db   256 dup(?)


.code
start:
    invoke GetModuleHandle, NULL
        MOV hInstance, EAX
    invoke DialogBoxParam, hInstance, IDD_KEYGEN, 0, ADDR DlgProc, 0
    invoke ExitProcess, EAX
;###############################################################################################################################################################
DlgProc proc hWin:DWORD,uMsg:DWORD,wParam:DWORD,lParam:DWORD
;###############################################################################################################################################################
    local @stPs:PAINTSTRUCT,@hDc,@stRect:RECT
    local @stBmp:BITMAP
    local hMemDC:HDC
       
       
.if uMsg==WM_INITDIALOG
    invoke LoadBitmap,hInstance,1007
        MOV hBitmap,EAX
        PUSH hBitmap
    invoke _WaveInit,addr stWaveObj,hWin,hBitmap,30,0
   
.if EAX
    invoke MessageBox,hWin,addr szError,addr szTitle,MB_OK or MB_ICONSTOP
        CALL _Quit
.else
.endif

;//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

        POP hBitmap
    invoke DeleteObject,hBitmap
    invoke _WaveEffect,addr stWaveObj,1,5,4,250
   
.elseif uMsg == WM_PAINT
    invoke BeginPaint,hWin,addr @stPs
        MOV @hDc,EAX
    invoke CreateCompatibleDC,@hDc
        MOV hMemDC,EAX
    invoke SelectObject,hMemDC,hBitmap
    invoke GetClientRect,hWin,addr @stRect
    invoke BitBlt,@hDc,10,10,@stRect.right,@stRect.bottom,hMemDC,0,0,MERGECOPY
    invoke DeleteDC,hMemDC
    invoke _WaveUpdateFrame,addr stWaveObj,eax,TRUE
    invoke EndPaint,hWin,addr @stPs
        XOR EAX,EAX
        XOR ECX,ECX
        RET
       
.elseif uMsg==WM_COMMAND
             .if wParam == IDC_GENERATE
    invoke GetDlgItemText,hWin,1002,addr szName,sizeof szName
;###############################################################################################################################################################
        MOV DWORD PTR [LenName], EAX        ; Stockage de eax dans LenName
        CMP EAX, 04h                        ; On compae la taille à 4d.
        JB @MinSize                         ; On saute si inférieur, le je saute si c'est égal.
        CMP EAX, 32h                        ; Puis on la compare à 50d (50 chars max).
        JA @MaxSize                         ; On saute vers le label appelé 'szSizeMax' si supérieur.
        XOR EAX,EAX                         ; MOV eax, 0
        XOR EBX,EBX                         ; MOV ebx, 0
        XOR ECX,ECX                         ; MOV ecx, 0
        XOR EDX,EDX                         ; MOV edx, 0
;###############################################################################################################################################################
; Routine
@Routine:
        MOV AL,BYTE PTR [ecx+szName]         ; Met dans AL chaque char du name un par un à chaque fois que je boucle ( car ECX est incrémenté ligne suivante ).
        INC ECX                              ; Incrémentation de ECX pour le définir comme compteur de chars contenus dans le name.
        XOR EAX,ECX
        ADD EBX,EAX                          ; Additionne ebx à eax. eax contenant les chars du name.
        CMP ECX,DWORD PTR [LenName]          ; Compare le nombre de chars du compteur au nombre de chars du name.
        JNE @Routine                         ; Boucle si le résultat du cmp précédent n'a pas été égal à 0, c'est à dire si ecx, le compteur, n'a pas été égal au nombre de chars du nom.
        IMUL EAX,EAX,6                       ; Multiplie le char pécédemment xoré par 6.
        SHL EBX,7                            ; Multiplie ebx par 2^7.
        ADD EAX,EBX                          ; Additionne eax à ebx.
        PUSH EAX
        PUSH offset szFormat                 ; ASCII "%X"
        PUSH offset szSerial
        CALL wsprintf
;###############################################################################################################################################################
    invoke SetDlgItemText,hWin,1003,addr szSerial
        RET
@MinSize:
    invoke MessageBox,hWin,addr szSizeMin,addr szCap,MB_ICONEXCLAMATION
        RET
@MaxSize:
    invoke MessageBox,hWin,addr szSizeMax,addr szCap,MB_ICONEXCLAMATION
        RET
   
.elseif uMsg==WM_DESTROY
    invoke DeleteObject,hBitmap
    invoke PostQuitMessage,NULL
.endif

.elseif uMsg == WM_CLOSE
        CALL _Quit
    invoke EndDialog,xWin,0    
.endif

.if wParam == IDC_COPY
    invoke SendDlgItemMessage,hWin,IDC_SERIAL,EM_SETSEL,0,-1
    invoke SendDlgItemMessage,hWin,IDC_SERIAL,WM_COPY,0,0
   
.elseif wParam == IDC_EXIT
    invoke SendMessage,hWin,WM_CLOSE,0,0
.endif     
        XOR EAX,EAX
        RET
   
DlgProc endp

_Quit proc

    invoke _WaveFree,addr stWaveObj
    invoke DestroyWindow,xWin
    invoke PostQuitMessage,NULL
        RET
_Quit endp
end start

uselib  MACRO   libname
include    libname.inc    
includelib libname.lib
ENDM

uselib     user32
uselib     kernel32
include    windows.inc
include    comctl32.inc
include    winmm.inc
include    gdi32.inc
include    C:\masm32\macros\macros.asm
include    WaveObject.asm
includelib user32.lib
includelib kernel32.lib
includelib gdi32.lib
includelib comctl32.lib
includelib winmm.lib


; Prototype des fonctions :
DlgProc PROTO :DWORD,:DWORD,:DWORD,:DWORD


 ; Définition des constantes ici :
.const
IDD_KEYGEN                 equ 1001
IDC_NAME                   equ 1002
IDC_SERIAL                 equ 1003
IDC_GENERATE               equ 1004
IDC_COPY                   equ 1005
IDC_EXIT                   equ 1006
IDC_OK                     equ 1010
LOGO                       equ 1007
LOGO2                      equ 1008

#define IDD_KEYGEN 1001
#define IDC_NAME 1002
#define IDC_SERIAL 1003
#define IDC_GENERATE 1004
#define IDC_COPY 1005
#define IDC_EXIT 1006
#define LOGO 1007
#define MyIcon 1013
#define LOGO2 1008

LOGO BITMAP DISCARDABLE "LOGO1.bmp"
LOGO2 BITMAP DISCARDABLE "LOGO2.bmp"
MyIcon ICON DISCARDABLE "favicon.ico"

IDD_KEYGEN DIALOGEX 0,0,262,205
CAPTION "Keygen By int_0x80"
FONT 8,"MS Sans Serif"
STYLE 0x10cc0000
EXSTYLE 0x00000000
BEGIN
    CONTROL "#1007",LOGO,"Static",0x1080020e,-7,-62,277,194,0x00000000
    CONTROL "#1008",LOGO2,"Static",0x1080020e,-7,74,277,137,0x00000000
    CONTROL "",IDC_NAME,"Edit",0x50010080,73,86,154,16,0x00000200
    CONTROL "",IDC_SERIAL,"Edit",0x50010080,73,121,154,16,0x00000200
    CONTROL "Generate",IDC_GENERATE,"Button",0x50010000,7,157,70,16,0x00000000
    CONTROL "Exit",IDC_EXIT,"Button",0x50010000,183,157,70,16,0x00000000
    CONTROL "Copy",IDC_COPY,"Button",0x50010000,96,157,70,16,0x00000000
END

;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Ë®²šÐ§¹û¹«ÓÃ×Ó³ÌÐò
; by ÂÞÔƱò£¬http://asm.yeah.net£¬luoyunbin@sina.com
; V 1.0.041019 --- ³õÊŒ°æ±Ÿ
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; ÔÚÔŽŽúÂëÖÐÖ»ÐèÒª include WaveObject.asm
; È»ºó°ŽÒÔϲœÖèµ÷ÓÃŒŽ¿É£º
;********************************************************************
; 1¡¢ŽŽœšË®²š¶ÔÏó£º
;    Òª¶ÔÒ»žöŽ°¿ÚœøÐл滭£¬Ê×ÏÈÒªŽŽœšÒ»žöË®²š¶ÔÏ󣚱Ÿº¯ÊýÉêÇëһЩ»º³åÇø£©
;    invoke _WaveInit,lpWaveObject,hWnd,hBmp,dwTime,dwType
;       lpWaveObject --> ÖžÏòÒ»žö¿ÕµÄ WAVE_OBJECT œá¹¹
;       hWnd --> Òª»æ»­Ë®²šÐ§¹ûµÄŽ°¿Ú£¬äÖÈŸºóµÄ͌Ƭœ«»­µœŽ°¿ÚµÄ¿Í»§ÇøÖÐ
;       hBmp --> ±³Ÿ°ÍŒÆ¬£¬»æ»­µÄ·¶Î§ŽóСͬ±³Ÿ°ÍŒÆ¬ŽóС
;       dwTime --> ˢеÄʱŒäŒäžô£šºÁÃ룩£¬œšÒéÖµ£º10¡«30
;   dwType --> =0 ±íÊŸÔ²ÐÎË®²š£¬=1±íÊŸÍÖÔ²ÐÍË®²š£šÓÃÓÚÍžÊÓЧ¹û£©
;       ·µ»ØÖµ£ºeax = 0£š³É¹Š£¬¶ÔÏó±»³õÊŒ»¯£©£¬eax = 1£šÊ§°Ü£©
;********************************************************************
; 2¡¢Èç¹û _WaveInit º¯Êý·µ»Ø³É¹Š£¬Ôò¶ÔÏó±»³õÊŒ»¯£¬œ«¶ÔÏóŽ«žøÏÂÁО÷ÖÖº¯Êý
;    ¿ÉÒÔʵÏÖž÷ÖÖЧ¹û£¬ÏÂÃ溯ÊýÖÐµÄ lpWaveObject ²ÎÊýÖžÏòÔÚ _WaveInit º¯Êý
;    ÖгõÊŒ»¯µÄ WAVE_OBJECT œá¹¹
;
;    ¡ò ÔÚÖž¶šÎ»Öá°ÈÓʯͷ¡±£¬Œ€ÆðË®²š
;       invoke _WaveDropStone,lpWaveObject,dwPosX,dwPosY,dwStoneSize,dwStoneWeight
;          dwPosX,dwPosY --> ÈÓÏÂʯͷµÄλÖÃ
;          dwStoneSize --> ʯͷµÄŽóС£¬ŒŽ³õÊŒµãµÄŽóС£¬œšÒéÖµ£º0¡«5
;          dwStoneWeight --> ʯͷµÄÖØÁ¿£¬Ÿö¶šÁ˲š×îºóÀ©É¢µÄ·¶Î§ŽóС£¬œšÒéÖµ£º10¡«1000
;
;    ¡ò ×Ô¶¯ÏÔÊŸÌØЧ
;       invoke _WaveEffect,lpWaveObject,dwEffectType,dwParam1,dwParam2,dwParam3
;          dwParam1,dwParam2,dwParam3 --> Ч¹û²ÎÊý£¬¶Ô²»Í¬µÄÌØЧÀàÐͲÎÊýº¬Ò岻ͬ
;          dwEffectType --> ÌØЧÀàÐÍ
;             0 --> ¹Ø±ÕÌØЧ
;             1 --> ÏÂÓ꣬Param1£œÃÜŒ¯Ëٶȣš0×îÃÜ£¬ÔœŽóԜϡÊ裩£¬œšÒéÖµ£º0¡«30
;                         Param2£œ×îŽóÓêµãÖ±Ÿ¶£¬œšÒéÖµ£º0¡«5
;                         Param3£œ×îŽóÓêµãÖØÁ¿£¬œšÒéÖµ£º50¡«250
;             2 --> Æûͧ£¬Param1£œËٶȣš0×îÂý£¬ÔœŽóÔœ¿ì£©£¬œšÒéÖµ£º0¡«8
;                         Param2£œŽ¬ŽóС£¬œšÒéÖµ£º0¡«4
;                         Param3£œË®²šÀ©É¢µÄ·¶Î§£¬œšÒéÖµ£º100¡«500
;             3 --> ·çÀË£¬Param1£œÃܶȣšÔœŽóÔœÃÜ£©£¬œšÒéÖµ£º50¡«300
;                         Param2£œŽóС£¬œšÒéÖµ£º2¡«5
;                         Param3£œÄÜÁ¿£¬œšÒéÖµ£º5¡«10
;
;    ¡ò Ž°¿Ú¿Í»§ÇøÇ¿ÖÆžüУšÓÃÓÚÔÚŽ°¿ÚµÄWM_PAINTÏûÏ¢ÖÐÇ¿ÖÆžüпͻ§¶Ë£©
;       .if     uMsg == WM_PAINT
;               invoke  BeginPaint,hWnd,addr @stPs
;               mov     @hDc,eax
;               invoke  _WaveUpdateFrame,lpWaveObject,eax,TRUE
;               invoke  EndPaint,hWnd,addr @stPs
;               xor     eax,eax
;               ret
;********************************************************************
; 3¡¢ÊÍ·ÅË®²š¶ÔÏó£º
;    Ê¹ÓÃÍê±Ïºó£¬±ØÐ뜫ˮ²š¶ÔÏóÊÍ·Å£š±Ÿº¯Êýœ«ÊÍ·ÅÉêÇëµÄ»º³åÇøÄÚŽæµÈ×ÊÔŽ£©
;       invoke  _WaveFree,lpWaveObject
;       lpWaveObject --> ÖžÏò WAVE_OBJECT œá¹¹
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; ʵÏÖÉϵÄÏžœÚ˵Ã÷£º
;
; 1¡¢ Ë®²šµÄÌØÕ÷£º
;   ¡ò À©É¢£ºÃ¿Ò»µãµÄ²š»áÀ©É¢µœÆäËÄÖܵÄλÖÃÖÐ
;   ¡ò Ë¥Œõ£ºÃ¿ŽÎÀ©É¢»áËðʧÉÙÁ¿ÄÜÁ¿£š·ñÔòË®²š»áÓÀ²»Í£Ö¹µÄÕðµŽÏÂÈ¥£©
;
; 2¡¢ ΪÁ˱£ŽæÁœžöʱ¿ÌÖеÄÄÜÁ¿·Ö²œÍŒ£¬¶ÔÏóÖжšÒå2žö»º³åÇøWave1ºÍWave2
;  £š±£ŽæÔÚlpWave1ºÍlpWave2ÖžÏòµÄ»º³åÇøÄÚ£©£¬Wave1Ϊµ±Ç°ÊýŸÝ£¬Wave2Ϊ
;   ÉÏÒ»Ö¡µÄÊýŸÝ£¬Ã¿ŽÎäÖȟʱœ«žùŸÝÉÏÃæµÄ2žöÌØÕ÷£¬ÓÉWave1µÄÊýŸÝŒÆËã³öÐÂ
;   ÄÜÁ¿·Ö±ðÍŒºó£¬±£ŽæµœWave2ÖУ¬È»ºóµ÷»»Wave1ºÍWave2£¬ÕâʱWave1ÈÔÊÇ×î
;   еÄÊýŸÝ¡£
;      ŒÆËãµÄ·œ·šÎª£¬Ä³žöµãµÄÄÜÁ¿£œµãËÄÖܵÄÉÏŽÎÄÜÁ¿µÄÆœŸùÖµ * Ë¥ŒõϵÊý
;   È¡ËÄÖܵÄÆœŸùÖµ±íÏÖÁËÀ©Õ¹ÌØÕ÷£¬³ËÒÔË¥ŒõϵÊý±íÏÖÁËË¥ŒõÌØÕ÷¡£
;      Õⲿ·ÖŽúÂëÔÚ _WaveSpread ×Ó³ÌÐòÖÐʵÏÖ¡£
;
; 3¡¢ ¶ÔÏóÔÚ lpDIBitsSource Öб£ŽæÁËԭʌλ͌µÄÊýŸÝ£¬Ã¿ŽÎäÖȟʱ£¬ÓÉÔ­ÊŒ
;   λ͌µÄÊýŸÝžùŸÝWave1Öб£ŽæµÄÄÜÁ¿·Ö²œÊýŸÝ²úÉúеÄλ͌¡£ŽÓÊÓŸõÉÏ¿Ž£¬
;   ijžöµãµÄÄÜÁ¿ÔœŽó£šË®²šÔœŽó£©£¬Ôò¹âÏßÕÛÉä³öԜԶŽŠµÄ³¡Ÿ°¡£
;      Ë㷚Ϊ£º¶ÔÓڵ㣚x,y£©£¬ÔÚWave1ÖÐÕÒ³öžÃµã£¬ŒÆËã³öÏàÁÚµãµÄ²šÄܲî
;  £šDxºÍDyÁœžöÊýŸÝ£©£¬ÔòÐÂλ͌ÏñËØ£šx,y£©£œÔ­ÊŒÎ»ÍŒÏñËØ£šx+Dx,y+Dy£©£¬
;   žÃËã·š±íÏÖÁËÄÜÁ¿ŽóСӰÏìÁËÏñËØÕÛÉäµÄÆ«ÒÆŽóС¡£
;      Õⲿ·ÖŽúÂëÔÚ _WaveRender ×Ó³ÌÐòÖÐʵÏÖ¡£
;
; 4¡¢ ÈÓʯͷµÄËã·šºÜºÃÀíœâ£¬ŒŽœ«Wave1ÖеÄijžöµãµÄÄÜÁ¿ÖµÖÃΪ·Ç0Öµ£¬ÊýÖµ
;   ÔœŽó£¬±íÊŸÈÓϵÄʯͷµÄÄÜÁ¿ÔœŽó¡£Ê¯Í·±ÈœÏŽó£¬Ôòœ«žÃµãËÄÖܵĵãÈ«²¿
;   ÖÃΪ·Ç0Öµ¡£
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;
;
;
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
ifndef      WAVEOBJ_INC
WAVEOBJ_INC equ 1
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
F_WO_ACTIVE     equ 0001h
F_WO_NEED_UPDATE    equ 0002h
F_WO_EFFECT     equ 0004h
F_WO_ELLIPSE        equ 0008h

WAVE_OBJECT     struct
 hWnd           dd  ?
 dwFlag         dd  ?   ; Œû F_WO_xxx ×éºÏ
;********************************************************************
 hDcRender      dd  ?
 hBmpRender     dd  ?
 lpDIBitsSource     dd  ?   ; Ô­ÊŒÏñËØÊýŸÝ
 lpDIBitsRender     dd  ?   ; ÓÃÓÚÏÔÊŸµœÆÁÄ»µÄÏñËØÊýŸÝ
 lpWave1        dd  ?   ; Ë®²šÄÜÁ¿ÊýŸÝ»º³å1
 lpWave2        dd  ?   ; Ë®²šÄÜÁ¿ÊýŸÝ»º³å2
;********************************************************************
 dwBmpWidth     dd  ?
 dwBmpHeight        dd  ?
 dwDIByteWidth      dd  ?   ; = (dwBmpWidth * 3 + 3) and ~3
 dwWaveByteWidth    dd  ?   ; = dwBmpWidth * 4
 dwRandom       dd  ?
;********************************************************************
; ÌØЧ²ÎÊý
;********************************************************************
 dwEffectType       dd  ?
 dwEffectParam1     dd  ?
 dwEffectParam2     dd  ?
 dwEffectParam3     dd  ?
;********************************************************************
; ÓÃÓÚÐÐŽ¬ÌØЧ
;********************************************************************
 dwEff2X        dd  ?
 dwEff2Y        dd  ?
 dwEff2XAdd     dd  ?
 dwEff2YAdd     dd  ?
 dwEff2Flip     dd  ?
;********************************************************************
 stBmpInfo      BITMAPINFO <>
WAVE_OBJECT     ends
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>


        .code
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; Ëæ»úÊý²úÉú×Ó³ÌÐò
; ÊäÈ룺Ҫ²úÉúµÄËæ»úÊýµÄ×îŽóÖµ£¬Êä³ö£ºËæ»úÊý
; žùŸÝ£º
; 1. Êýѧ¹«Êœ Rnd=(Rnd*I+J) mod K Ñ­»·»ØŽøÉú³É K ŽÎÒÔÄÚ²»ÖØžŽµÄ
;    Î±Ëæ»úÊý£¬µ«K,I,J±ØÐëΪËØÊý
; 2. 2^(2n-1)-1 ±Ø¶šÎªËØÊý£šŒŽ2µÄÆæÊýŽÎ·œŒõ1£©
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveRandom16   proc    _lpWaveObject

        mov ebx,_lpWaveObject
        assume  ebx:ptr WAVE_OBJECT
        push    edx
        push    ecx
        mov eax,[ebx].dwRandom
        mov ecx,32768-1 ;2^15-1
        mul ecx
        add eax,2048-1  ;2^11-1
        adc edx,0
        mov ecx,2147483647  ;2^31-1
        div ecx
        mov eax,[ebx].dwRandom
        mov [ebx].dwRandom,edx
        and eax,0000ffffh
        pop ecx
        pop edx
        ret

_WaveRandom16   endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveRandom proc    uses ebx ecx edx _lpWaveObject,_dwMax

        invoke  _WaveRandom16,_lpWaveObject
        mov edx,eax
        invoke  _WaveRandom16,_lpWaveObject
        shl eax,16
        or  ax,dx
        mov ecx,_dwMax
        or  ecx,ecx
        jz  @F
        xor edx,edx
        div ecx
        mov eax,edx
        @@:
        ret

_WaveRandom endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; ²šÄÜÀ©É¢
; Ëã·š£º
; Wave2(x,y) = (Wave1(x+1,y)+Wave1(x-1,y)+Wave1(x,y+1)+Wave1(x,y-1))/2-Wave2(x,y)
; Wave2(x,y) = Wave2(x,y) - Wave2(x,y) >> 5
; xchg Wave1,Wave2
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveSpread proc    _lpWaveObject

        pushad
        mov ebx,_lpWaveObject
        assume  ebx:ptr WAVE_OBJECT
;********************************************************************
        test    [ebx].dwFlag,F_WO_ACTIVE
        jz  _Ret

        mov esi,[ebx].lpWave1
        mov edi,[ebx].lpWave2
        mov ecx,[ebx].dwBmpWidth

        mov eax,[ebx].dwBmpHeight
        dec eax
        mul ecx
;********************************************************************
; ebx = width
; ecx = i£¬eax = max
;********************************************************************
        .while  ecx < eax
            push    eax
            .if [ebx].dwFlag & F_WO_ELLIPSE
                mov edx,[esi+ecx*4-1*4]
                add edx,[esi+ecx*4+1*4]
                add edx,[esi+ecx*4-2*4]
                add edx,[esi+ecx*4+2*4]
                lea edx,[edx+edx*2]
                add edx,[esi+ecx*4-3*4]
                add edx,[esi+ecx*4-3*4]
                add edx,[esi+ecx*4+3*4]
                add edx,[esi+ecx*4+3*4]

                lea eax,[esi+ecx*4]
                sub eax,[ebx].dwWaveByteWidth
                mov eax,[eax]
                shl eax,3
                add edx,eax

                lea eax,[esi+ecx*4]
                add eax,[ebx].dwWaveByteWidth
                mov eax,[eax]
                shl eax,3
                add edx,eax

                sar edx,4
                sub edx,[edi+ecx*4]

                mov eax,edx
                sar eax,5
                sub edx,eax

                mov [edi+ecx*4],edx
            .else
                mov edx,[esi+ecx*4-1*4]
                add edx,[esi+ecx*4+1*4]

                lea eax,[esi+ecx*4]
                sub eax,[ebx].dwWaveByteWidth
                add edx,[eax]

                lea eax,[esi+ecx*4]
                add eax,[ebx].dwWaveByteWidth
                add edx,[eax]

                sar edx,1
                sub edx,[edi+ecx*4]

                mov eax,edx
                sar eax,5
                sub edx,eax

                mov [edi+ecx*4],edx
            .endif
            pop eax
            inc ecx
        .endw

        mov [ebx].lpWave1,edi
        mov [ebx].lpWave2,esi
_Ret:
;********************************************************************
        assume  ebx:nothing
        popad
        ret

_WaveSpread endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; esi -> edi, ecx = line width
; return = (4*Pixel(x,y)+3*Pixel(x-1,y)+3*Pixel(x+1,y)+3*Pixel(x,y+1)+3*Pixel(x,y-1))/16
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveGetPixel:
        movzx   eax,byte ptr [esi]
        shl eax,2
        movzx   edx,byte ptr [esi+3]
        lea edx,[edx+2*edx]
        add eax,edx
        movzx   edx,byte ptr [esi-3]
        lea edx,[edx+2*edx]
        add eax,edx
        movzx   edx,byte ptr [esi+ecx]
        lea edx,[edx+2*edx]
        add eax,edx
        mov edx,esi
        sub edx,ecx
        movzx   edx,byte ptr [edx]
        lea edx,[edx+2*edx]
        add eax,edx
        shr eax,4
        mov [edi],al
        inc esi
        inc edi
        ret
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; äÖÈŸ×Ó³ÌÐò£¬œ«ÐµÄÖ¡ÊýŸÝäÖÈŸµœ lpDIBitsRender ÖÐ
; Ëã·š£º
; posx = Wave1(x-1,y)-Wave1(x+1,y)+x
; posy = Wave1(x,y-1)-Wave1(x,y+1)+y
; SourceBmp(x,y) = DestBmp(posx,posy)
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveRender proc    _lpWaveObject
        local   @dwPosX,@dwPosY,@dwPtrSource,@dwFlag

        pushad
        xor eax,eax
        mov @dwFlag,eax
        mov ebx,_lpWaveObject
        assume  ebx:ptr WAVE_OBJECT

        test    [ebx].dwFlag,F_WO_ACTIVE
        jz  _Ret

        or  [ebx].dwFlag,F_WO_NEED_UPDATE
        mov esi,[ebx].lpWave1
        mov edi,[ebx].dwWaveByteWidth   ; edi = ÏñËØÖžÕë

        xor ecx,ecx
        inc ecx     ; ecx=i  --  i=1; i<height; i++
_Loop1:
        xor edx,edx     ; edx=j  --  j=0; j<width; j++
_Loop2:
        push    edx
;********************************************************************
; PosY=i+ÏñËØÉÏ1ÄÜÁ¿-ÏñËØÏÂ1ÄÜÁ¿
; PosX=j+ÏñËØ×ó1ÄÜÁ¿-ÏñËØÓÒ1ÄÜÁ¿
;********************************************************************
        mov eax,edi
        sub eax,[ebx].dwWaveByteWidth
        mov eax,[esi+eax]
        mov @dwPosY,eax

        mov eax,[ebx].dwWaveByteWidth
        lea eax,[edi+eax]
        mov eax,[esi+eax]
        sub @dwPosY,eax
        add @dwPosY,ecx

        mov eax,[esi+edi-4]
        sub eax,[esi+edi+4]
        add eax,edx         ;@dwPosX = eax
        mov @dwPosX,eax

        cmp eax,0
        jl  _Continue
        cmp eax,[ebx].dwBmpWidth
        jge _Continue
        mov eax,@dwPosY
        cmp eax,0
        jl  _Continue
        cmp eax,[ebx].dwBmpHeight
        jge _Continue
;********************************************************************
; ptrSource = dwPosY * dwDIByteWidth + dwPosX * 3
; ptrDest = i * dwDIByteWidth + j * 3
;********************************************************************
        mov eax,@dwPosX
        lea eax,[eax+eax*2]
        mov @dwPosX,eax
        push    edx
        mov eax,@dwPosY
        mul [ebx].dwDIByteWidth
        add eax,@dwPosX
        mov @dwPtrSource,eax

        mov eax,ecx
        mul [ebx].dwDIByteWidth
        pop edx
        lea edx,[edx+edx*2]
        add eax,edx         ;@dwPtrDest = eax
;********************************************************************
; äÖÈŸÏñËØ [ptrDest] = Ô­ÊŒÏñËØ [ptrSource]
;********************************************************************
        pushad
        mov ecx,@dwPtrSource
        mov esi,[ebx].lpDIBitsSource
        mov edi,[ebx].lpDIBitsRender
        lea esi,[esi+ecx]
        lea edi,[edi+eax]
        .if ecx !=  eax
            or  @dwFlag,1   ;Èç¹ûŽæÔÚÔŽÏñËغÍÄ¿±êÏñËز»Í¬£¬Ôò±íÊŸ»¹Ôڻ׎̬
            mov ecx,[ebx].dwDIByteWidth
            call    _WaveGetPixel
            call    _WaveGetPixel
            call    _WaveGetPixel
        .else
            cld
            movsw
            movsb
        .endif
        popad
;********************************************************************
; ŒÌÐøÑ­»·
;********************************************************************
_Continue:
        pop edx
        inc edx
        add edi,4       ; ÏñËØ++
        cmp edx,[ebx].dwBmpWidth
        jb  _Loop2

        inc ecx
        mov eax,[ebx].dwBmpHeight
        dec eax
        cmp ecx,eax
        jb  _Loop1
;********************************************************************
; œ«äÖÈŸµÄÏñËØÊýŸÝ¿œ±Žµœ hDc ÖÐ
;********************************************************************
        invoke  SetDIBits,[ebx].hDcRender,[ebx].hBmpRender,0,[ebx].dwBmpHeight,\
            [ebx].lpDIBitsRender,addr [ebx].stBmpInfo,DIB_RGB_COLORS
        .if ! @dwFlag
            and [ebx].dwFlag,not F_WO_ACTIVE
        .endif
_Ret:
;********************************************************************
        assume  ebx:nothing
        popad
        ret

_WaveRender endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveUpdateFrame    proc    _lpWaveObject,_hDc,_bIfForce

        pushad
        mov ebx,_lpWaveObject
        assume  ebx:ptr WAVE_OBJECT

        cmp _bIfForce,0
        jnz @F
        .if [ebx].dwFlag & F_WO_NEED_UPDATE
            @@:
            invoke  BitBlt,_hDc,0,0,[ebx].dwBmpWidth,[ebx].dwBmpHeight,\
                [ebx].hDcRender,0,0,SRCCOPY
            and [ebx].dwFlag,not F_WO_NEED_UPDATE
        .endif

        assume  ebx:nothing
        popad
        ret

_WaveUpdateFrame    endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; ÈÓÒ»¿éʯͷ
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveDropStone  proc    _lpWaveObject,_dwX,_dwY,_dwSize,_dwWeight
        local   @dwMaxX,@dwMaxY

        pushad
        mov ebx,_lpWaveObject
        assume  ebx:ptr WAVE_OBJECT
;********************************************************************
; ŒÆË㷶Χ
;********************************************************************
        mov edx,_dwSize
        shr edx,1

        mov eax,_dwX
        mov esi,_dwY

        mov ecx,eax
        mov edi,esi
        add eax,edx     ; x + size
        sub ecx,edx     ; x - size

        push    edx
        .if [ebx].dwFlag & F_WO_ELLIPSE
            shr edx,1
        .endif
        add esi,edx     ; y + size
        sub edi,edx     ; y - size
        pop edx

        shl edx,1
        .if ! edx
            inc edx
        .endif
        mov _dwSize,edx
;********************************************************************
; ÅжϷ¶Î§µÄºÏ·šÐÔ
;********************************************************************
        inc eax
        cmp eax,[ebx].dwBmpWidth
        jge _Ret
        cmp ecx,1
        jl  _Ret
        inc esi
        cmp esi,[ebx].dwBmpHeight
        jge _Ret
        cmp edi,1
        jl  _Ret

        dec eax
        dec esi
;********************************************************************
; œ«·¶Î§ÄڵĵãµÄÄÜÁ¿ÖÃΪ _dwWeight
;********************************************************************
        mov @dwMaxX,eax
        mov @dwMaxY,esi
        .while  ecx <=  @dwMaxX
            push    edi
            .while  edi <=  @dwMaxY
                mov eax,ecx
                sub eax,_dwX
                imul    eax
                push    eax
                mov eax,edi
                sub eax,_dwY
                imul    eax
                pop edx
                add eax,edx
                push    eax
                mov eax,_dwSize
                imul    eax
                pop edx
                .if edx <=  eax
                    mov eax,edi
                    mul [ebx].dwBmpWidth
                    add eax,ecx
                    shl eax,2
                    add eax,[ebx].lpWave1
                    push    _dwWeight
                    pop [eax]
                .endif
                inc edi
            .endw
            pop edi
            inc ecx
        .endw
        or  [ebx].dwFlag,F_WO_ACTIVE
;********************************************************************
_Ret:
        assume  ebx:nothing
        popad
        ret

_WaveDropStone  endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; ŒÆËãÀ©É¢ÊýŸÝ¡¢äÖȟλ͌¡¢žüÐÂŽ°¿Ú¡¢ŽŠÀíÌØЧµÄ¶šÊ±Æ÷¹ý³Ì
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveTimerProc  proc    _hWnd,_uMsg,_idEvent,_dwTime

        pushad
        mov ebx,_idEvent
        assume  ebx:ptr WAVE_OBJECT

        invoke  _WaveSpread,ebx
        invoke  _WaveRender,ebx
        .if [ebx].dwFlag & F_WO_NEED_UPDATE
            invoke  GetDC,[ebx].hWnd
            invoke  _WaveUpdateFrame,ebx,eax,FALSE
            invoke  ReleaseDC,[ebx].hWnd,eax
        .endif
;********************************************************************
; ÌØЧŽŠÀí
;********************************************************************
        test    [ebx].dwFlag,F_WO_EFFECT
        jz  _Ret
        mov eax,[ebx].dwEffectType
;********************************************************************
; Type = 1 Óêµã£¬Param1£œËٶȣš0×î¿ì£¬ÔœŽóÔœÂý£©£¬Param2£œÓêµãŽóС£¬Param3£œÄÜÁ¿
;********************************************************************
        .if eax ==  1
            mov eax,[ebx].dwEffectParam1
            or  eax,eax
            jz  @F
            invoke  _WaveRandom,ebx,eax
            .if ! eax
                @@:
                mov eax,[ebx].dwBmpWidth
                dec eax
                dec eax
                invoke  _WaveRandom,ebx,eax
                inc eax
                mov ecx,eax

                mov eax,[ebx].dwBmpHeight
                dec eax
                dec eax
                invoke  _WaveRandom,ebx,eax
                inc eax
                mov edx,eax

                invoke  _WaveRandom,ebx,[ebx].dwEffectParam2
                inc eax
                mov esi,eax
                invoke  _WaveRandom,ebx,[ebx].dwEffectParam3
                add eax,50
                invoke  _WaveDropStone,ebx,ecx,edx,esi,eax
            .endif
;********************************************************************
; Type = 2 ÐÐŽ¬£¬Param1£œËٶȣš0×î¿ì£¬ÔœŽóÔœ¿ì£©£¬Param2£œŽóС£¬Param3£œÄÜÁ¿
;********************************************************************
        .elseif eax ==  2
            inc [ebx].dwEff2Flip
            test    [ebx].dwEff2Flip,1
            jnz _Ret

            mov ecx,[ebx].dwEff2X
            mov edx,[ebx].dwEff2Y
            add ecx,[ebx].dwEff2XAdd
            add edx,[ebx].dwEff2YAdd

            cmp ecx,1
            jge @F
            sub ecx,1
            neg ecx
            neg [ebx].dwEff2XAdd
            @@:
            cmp edx,1
            jge @F
            sub edx,1
            neg edx
            neg [ebx].dwEff2YAdd
            @@:
            mov eax,[ebx].dwBmpWidth
            dec eax
            cmp ecx,eax
            jl  @F
            sub ecx,eax
            xchg    eax,ecx
            sub ecx,eax
            neg [ebx].dwEff2XAdd
            @@:
            mov eax,[ebx].dwBmpHeight
            dec eax
            cmp edx,eax
            jl  @F
            sub edx,eax
            xchg    eax,edx
            sub edx,eax
            neg [ebx].dwEff2YAdd
            @@:
            mov [ebx].dwEff2X,ecx
            mov [ebx].dwEff2Y,edx
            invoke  _WaveDropStone,ebx,ecx,edx,[ebx].dwEffectParam2,[ebx].dwEffectParam3
;********************************************************************
; Type = 3 ²šÀË£¬Param1£œÃܶȣ¬Param2£œŽóС£¬Param3£œÄÜÁ¿
;********************************************************************
        .elseif eax ==  3
            xor edi,edi
            .while  edi <=  [ebx].dwEffectParam1
                mov eax,[ebx].dwBmpWidth
                dec eax
                dec eax
                invoke  _WaveRandom,ebx,eax
                inc eax
                mov ecx,eax

                mov eax,[ebx].dwBmpHeight
                dec eax
                dec eax
                invoke  _WaveRandom,ebx,eax
                inc eax
                mov edx,eax

                invoke  _WaveRandom,ebx,[ebx].dwEffectParam2
                inc eax
                mov esi,eax
                invoke  _WaveRandom,ebx,[ebx].dwEffectParam3
                invoke  _WaveDropStone,ebx,ecx,edx,esi,eax
                inc edi
            .endw
        .endif
_Ret:
        assume  ebx:nothing
        popad
        ret

_WaveTimerProc  endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; ÊͷŶÔÏó
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveFree   proc    _lpWaveObject

        pushad
        mov ebx,_lpWaveObject
        assume  ebx:ptr WAVE_OBJECT
;********************************************************************
        .if [ebx].hDcRender
            invoke  DeleteDC,[ebx].hDcRender
        .endif
        .if [ebx].hBmpRender
            invoke  DeleteObject,[ebx].hBmpRender
        .endif
        .if [ebx].lpDIBitsSource
            invoke  GlobalFree,[ebx].lpDIBitsSource
        .endif
        .if [ebx].lpDIBitsRender
            invoke  GlobalFree,[ebx].lpDIBitsRender
        .endif
        .if [ebx].lpWave1
            invoke  GlobalFree,[ebx].lpWave1
        .endif
        .if [ebx].lpWave2
            invoke  GlobalFree,[ebx].lpWave2
        .endif
        invoke  KillTimer,[ebx].hWnd,ebx
        invoke  RtlZeroMemory,ebx,sizeof WAVE_OBJECT
;********************************************************************
        assume  ebx:nothing
        popad
        ret

_WaveFree   endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; ³õÊŒ»¯¶ÔÏó
; ²ÎÊý£º_lpWaveObject £œ ÖžÏò WAVE_OBJECTµÄÖžÕë
; ·µ»Ø£ºeax = 0 ³É¹Š¡¢= 1 ʧ°Ü
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveInit   proc    _lpWaveObject,_hWnd,_hBmp,_dwSpeed,_dwType
        local   @stBmp:BITMAP,@dwReturn

        pushad
        xor eax,eax
        mov @dwReturn,eax
        mov ebx,_lpWaveObject
        assume  ebx:ptr WAVE_OBJECT
        invoke  RtlZeroMemory,ebx,sizeof WAVE_OBJECT

        .if _dwType
            or  [ebx].dwFlag,F_WO_ELLIPSE
        .endif
;********************************************************************
; »ñȡλ͌³ßŽç
;********************************************************************
        push    _hWnd
        pop [ebx].hWnd
        invoke  GetTickCount
        mov [ebx].dwRandom,eax

        invoke  GetObject,_hBmp,sizeof BITMAP,addr @stBmp
        .if ! eax
            @@:
            inc @dwReturn
            jmp _Ret
        .endif
        mov eax,@stBmp.bmHeight
        mov [ebx].dwBmpHeight,eax
        cmp eax,3
        jle @B
        mov eax,@stBmp.bmWidth
        mov [ebx].dwBmpWidth,eax
        cmp eax,3
        jle @B

        push    eax
        shl eax,2
        mov [ebx].dwWaveByteWidth,eax
        pop eax
        lea eax,[eax+eax*2]
        add eax,3
        and eax,not 0011b
        mov [ebx].dwDIByteWidth,eax
;********************************************************************
; ŽŽœšÓÃÓÚäÖÈŸµÄλ͌
;********************************************************************
        invoke  GetDC,_hWnd
        mov esi,eax
        invoke  CreateCompatibleDC,esi
        mov [ebx].hDcRender,eax
        invoke  CreateCompatibleBitmap,esi,[ebx].dwBmpWidth,[ebx].dwBmpHeight
        mov [ebx].hBmpRender,eax
        invoke  SelectObject,[ebx].hDcRender,eax
;********************************************************************
; ·ÖÅ䲚ÄÜ»º³åÇø
;********************************************************************
        mov eax,[ebx].dwWaveByteWidth
        mul [ebx].dwBmpHeight
        mov edi,eax
        invoke  GlobalAlloc,GPTR,edi
        mov [ebx].lpWave1,eax
        invoke  GlobalAlloc,GPTR,edi
        mov [ebx].lpWave2,eax
;********************************************************************
; ·ÖÅäÏñËØ»º³åÇø
;********************************************************************
        mov eax,[ebx].dwDIByteWidth
        mul [ebx].dwBmpHeight
        mov edi,eax
        invoke  GlobalAlloc,GPTR,edi
        mov [ebx].lpDIBitsSource,eax
        invoke  GlobalAlloc,GPTR,edi
        mov [ebx].lpDIBitsRender,eax
;********************************************************************
; »ñÈ¡Ô­ÊŒÏñËØÊýŸÝ
;********************************************************************
        mov [ebx].stBmpInfo.bmiHeader.biSize,sizeof BITMAPINFOHEADER
        push    [ebx].dwBmpWidth
        pop [ebx].stBmpInfo.bmiHeader.biWidth
        mov eax,[ebx].dwBmpHeight
        neg eax
        mov [ebx].stBmpInfo.bmiHeader.biHeight,eax
        inc [ebx].stBmpInfo.bmiHeader.biPlanes
        mov [ebx].stBmpInfo.bmiHeader.biBitCount,24
        mov [ebx].stBmpInfo.bmiHeader.biCompression,BI_RGB
        mov [ebx].stBmpInfo.bmiHeader.biSizeImage,0

        invoke  CreateCompatibleDC,esi
        push    eax
        invoke  SelectObject,eax,_hBmp
        invoke  ReleaseDC,_hWnd,esi
        pop eax
        mov esi,eax

        invoke  GetDIBits,esi,_hBmp,0,[ebx].dwBmpHeight,[ebx].lpDIBitsSource,\
            addr [ebx].stBmpInfo,DIB_RGB_COLORS
        invoke  GetDIBits,esi,_hBmp,0,[ebx].dwBmpHeight,[ebx].lpDIBitsRender,\
            addr [ebx].stBmpInfo,DIB_RGB_COLORS
        invoke  DeleteDC,esi

        .if ![ebx].lpWave1 || ![ebx].lpWave2 || ![ebx].lpDIBitsSource ||\
            ![ebx].lpDIBitsRender || ![ebx].hDcRender
            invoke  _WaveFree,ebx
            inc @dwReturn
        .endif

        invoke  SetTimer,_hWnd,ebx,_dwSpeed,addr _WaveTimerProc

        or  [ebx].dwFlag,F_WO_ACTIVE or F_WO_NEED_UPDATE
        invoke  _WaveRender,ebx
        invoke  GetDC,[ebx].hWnd
        invoke  _WaveUpdateFrame,ebx,eax,TRUE
        invoke  ReleaseDC,[ebx].hWnd,eax
;********************************************************************
_Ret:
        assume  ebx:nothing
        popad
        mov eax,@dwReturn
        ret

_WaveInit   endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
; һЩÌØЧ
; ÊäÈ룺_dwType = 0   ¹Ø±ÕÌØЧ
;   _dwType <> 0    ¿ªÆôÌØЧ£¬²ÎÊýŸßÌåŒûÉÏÃæ
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
_WaveEffect proc    uses ebx eax _lpWaveObject,\
            _dwType,_dwParam1,_dwParam2,_dwParam3
        local   @dwMaxX,@dwMaxY

        mov ebx,_lpWaveObject
        assume  ebx:ptr WAVE_OBJECT
;********************************************************************
        mov eax,_dwType
        .if eax ==  0
;********************************************************************
; ¹Ø±ÕÌØЧ
;********************************************************************
            and [ebx].dwFlag,not F_WO_EFFECT
            mov [ebx].dwEffectType,eax
        .elseif eax ==  2
;********************************************************************
; ÐÐŽ¬ÌØЧ
;********************************************************************
            mov eax,_dwParam1
            mov [ebx].dwEff2XAdd,eax
            mov [ebx].dwEff2YAdd,eax

            mov eax,[ebx].dwBmpWidth
            dec eax
            dec eax
            invoke  _WaveRandom,ebx,eax
            inc eax
            mov [ebx].dwEff2X,eax

            mov eax,[ebx].dwBmpHeight
            dec eax
            dec eax
            invoke  _WaveRandom,ebx,eax
            inc eax
            mov [ebx].dwEff2Y,eax

            jmp @F
        .else
;********************************************************************
; ĬÈÏ
;********************************************************************
            @@:
            push    _dwType
            pop [ebx].dwEffectType
            push    _dwParam1
            pop [ebx].dwEffectParam1
            push    _dwParam2
            pop [ebx].dwEffectParam2
            push    _dwParam3
            pop [ebx].dwEffectParam3
            or  [ebx].dwFlag,F_WO_EFFECT
        .endif
;********************************************************************
        assume  ebx:nothing
        ret

_WaveEffect endp
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
;
;
;
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
endif
;>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>